jem/build.gradle

apply plugin: 'groovy'
apply plugin: 'maven'
apply plugin: 'codenarc'

version = '0.1'
description = 'A Groovy-based library for managing Ruby gems'

repositories {
    jcenter()
}

dependencies {
    compile "org.codehaus.groovy:groovy-all:2.4.0+"

    compile 'joda-time:joda-time:2.6+'

    /* Used for processing yaml files inside of gems */
    compile 'com.fasterxml.jackson.dataformat:jackson-dataformat-yaml:2.5.4'
    compile 'com.fasterxml.jackson.core:jackson-annotations:2.5.4'
    compile 'com.fasterxml.jackson.core:jackson-databind:2.5.4'

    /* Used for reading into tar, aka gem, files */
    compile 'org.apache.commons:commons-vfs2:2.0+'

    codenarc "org.codenarc:CodeNarc:0.24"

    testCompile "org.spockframework:spock-core:1.0-groovy-2.4"
}

codenarc {
    sourceSets = [sourceSets.main]
    configFile = file("${projectDir}/gradle/codenarc.rules")
}

test {
    testLogging {
        showStandardStreams = true
        exceptionFormat "full"
    }
}

plugins.withType(JavaPlugin) {
    sourceCompatibility = 1.7
    targetCompatibility = 1.7


    project.tasks.withType(JavaCompile) { task ->
        task.sourceCompatibility = project.sourceCompatibility
        task.targetCompatibility = project.targetCompatibility
    }

    project.tasks.withType(GroovyCompile) { task ->
        task.sourceCompatibility = project.sourceCompatibility
        task.targetCompatibility = project.targetCompatibility
    }
}

/* Add the sources jar to the list of artifacts to publish */
task sourcesJar(type: Jar, dependsOn: classes) {
    classifier = 'sources'
    from sourceSets.main.allSource
}

task groovydocJar(type: Jar) {
    dependsOn groovydoc
    classifier = 'groovydoc'
    from groovydoc.destinationDir
}

artifacts {
    archives sourcesJar
    archives groovydocJar
}

assemble.dependsOn check
assemble.dependsOn groovydocJar
assemble.dependsOn sourcesJar